【メモ】LTspiceにTLC555の登録

TI社のTLC555（CMOSタイプ）の登録方法です。以下の手順で登録すると、メニューの Edit → Component で出てきたモデルの中に TLC555 が出てきます。

（１） LT-Spiceのフォルダの中の lib フォルダ→symフォルダの中に、以下のファイルを、TLC555.asy という名前で、テキスト形式で保存する（Notepadなどのテキストエディタを開いて、以下の文章をコピー＆ペーストして、TLC555.asy という名前で、テキスト形式で保存する）。
Version 4
SymbolType CELL
LINE Normal -20 -128 -20 -112
LINE Normal 20 -128 20 -112
LINE Normal -8 -100 8 -100
RECTANGLE Normal -112 -128 112 128
ARC Normal -20 -124 4 -100 -20 -112 -8 -100
ARC Normal -4 -124 20 -100 8 -100 20 -112
WINDOW 0 0 -144 Center 2
WINDOW 3 0 144 Center 2
SYMATTR Value TLC555
SYMATTR Prefix X
SYMATTR Description LinCMOS Timer
SYMATTR ModelFile TLC555.lib
SYMATTR Value2 VDD=5 RONX=1
PIN -112 -96 LEFT 8
PINATTR PinName GND
PINATTR SpiceOrder 1
PIN -112 -32 LEFT 8
PINATTR PinName TRIG
PINATTR SpiceOrder 2
PIN -112 32 LEFT 8
PINATTR PinName OUT
PINATTR SpiceOrder 3
PIN -112 96 LEFT 8
PINATTR PinName RST
PINATTR SpiceOrder 4
PIN 112 96 RIGHT 8
PINATTR PinName CV
PINATTR SpiceOrder 5
PIN 112 32 RIGHT 8
PINATTR PinName THRS
PINATTR SpiceOrder 6
PIN 112 -32 RIGHT 8
PINATTR PinName DIS
PINATTR SpiceOrder 7
PIN 112 -96 RIGHT 8
PINATTR PinName VCC
PINATTR SpiceOrder 8

（２） LT-Spiceのフォルダの中の lib フォルダ→subフォルダの中に、以下のファイルを、TLC555.lib という名前で、テキスト形式で保存する。
.subckt TLC555 1 2 3 4 5 6 7 8 vdd1={VDD} RonX1={RONX}
.param Ron_d=RonX1*(1+7*(14.3/{vdd1-0.7})**0.75)
.param Ron_oh=RonX1*(10+60*(14.3/{vdd1-0.7})**0.75)
.param Ron_ol=RonX1*(2+15*(14.3/{vdd1-0.7})**0.75)
A1 N001 2 1 1 1 1 N003 1 SCHMITT Vt=0 Vh=1m
R1 N001 1 100K
R2 5 N001 100K
R3 8 5 100K
S1 1 7 N012 1 DS
A2 N006 N003 1 1 1 1 N004 1 SRFLOP Trise=100n tripdt=10n
A3 6 5 1 1 1 1 N006 1 SCHMITT Vt=0 Vh=1m
S2 8 3 N010 1 OH
S3 3 1 1 N010 OL
A6 1 N013 1 N004 1 1 N012 1 OR Ref=.5 Vlow=-1 Trise=100n
R7 8 1 16K
R8 4 1 1G
R9 2 1 1G
R10 6 1 1G
A4 1 N004 1 N013 1 N010 1 1 OR ref=.5 Vlow=-1 Trise=100n
A5 4 1 1 1 1 N013 1 1 SCHMITT Vt=1.1 Vh=1m
* Ron depends on VDD.
.model DS SW(Ron={Ron_d} Roff=1G Vt=.5 Vh=-.4)
.model OH SW(Ron={Ron_oh} Roff=1Meg Vt=0 Vh=-.8)
.model OL SW(Ron={Ron_ol} Roff=1Meg Vt=0 Vh=-.8)
* Values for VDD=15V from TI data sheet.
*.model DS SW(Ron=7 Roff=1G Vt=.5 Vh=-.4)
*.model OH SW(Ron=80 Roff=1Meg Vt=0 Vh=-.8)
*.model OL SW(Ron=13 Roff=1Meg Vt=0 Vh=-.8)
* Values for VDD=5V from TI data sheet.
*.model DS SW(Ron=15 Roff=1G Vt=.5 Vh=-.4)
*.model OH SW(Ron=200 Roff=1Meg Vt=0 Vh=-.8)
*.model OL SW(Ron=25 Roff=1Meg Vt=0 Vh=-.8)
* Values for VDD=2V from TI data sheet.
*.model DS SW(Ron=30 Roff=1G Vt=.5 Vh=-.4)
*.model OH SW(Ron=330 Roff=1Meg Vt=0 Vh=-.8)
*.model OL SW(Ron=70 Roff=1Meg Vt=0 Vh=-.8)
.ends TLC555