昔、ハードオフで買った
CASIO PB-500(¥800)
に入っていたプログラム。
-------- PROG 0 --------
10 PRINT " *タンカ リマワリ ケイサン*"
12 INPUT "キサンビ=";A
14 INPUT "マンキビ=";B
16 INPUT "クーポンレート=";C
20 GOSUB PROG 9
30 INPUT "タンカ OR リマワリ=";D
35 IF C=0 THEN 90
40 IF D>=40 THEN 70
50 K=(R+C*Z)/(1+D*Z/R)
55 V=10^5; GOSUB PROG 8
60 PRINT "タンカ=";K: GOTO 30
70 K=(C*Z+(R-D))*R/(D*Z)
75 V=10^5: GOSUB PROG 8
80 PRINT "リマワリ=";K: GOTO 30
90 IF Z=<1 THEN 40
100 IF D>=40 THEN K=((R/D)^(1/Z)-1)*R: GOTO 75
110 K=R/(1+D/R)^Z: GOTO 55
-------- PROG 1 --------
5 PRINT " * ウケワタシ ケイサン *"
10 INPUT "ウケワタシビ=";B
15 INPUT "クーポンレート=";C
20 GOSUB PROG 7
40 INPUT "ゼンカイリバライビ(OR ハッコウビ)";A
50 GOSUB PROG 9
60 INPUT "コウニュウ:1(Y) OR 0(N)";X$:T=0
70 IF X$="0" THEN INPUT "トリヒキゼイリツ(マンブンノ)=";T:T=T/R^2
80 INPUT "リシゼイリツ(%)=";U:U=1-U/R
82 INPUT "イタクテスウリョウ(セン)=";M
90 K=Q+J
100 IF O=P THEN Y=0: GOTO 120
110 K=C*U*K/365:V=10^7: GOSUB PROG 8:Y=K
120 INPUT "ガクメン(100マン)=";D
125 INPUT "タンカ=";E
130 F=D*E*R^2
140 H=INT(F*T)
150 G=INT(D*Y*R^2)
160 L=D*M*R
170 IF X$="1" THEN I=F+G+L: GOTO 190
180 I=F+G-H-L
190 PRINT "カガク=";F,"ケイカリシ=";G,"トリヒキゼイ=";H
200 PRINT "テスウリョウ=";L,"ウケワタシキンガク=";I
210 GOTO 120
-------- PROG 2 --------
5 PRINT "* ゲンサキ ケイサン *"
10 INPUT "スタートビ=";A,"エンドビ=";B,"クーポンレート=";C
20 GOSUB PROG 9:F=Q
30 INPUT "トチュウ リバライビ=";B:E=B:IF E=0 THEN 50
40 GOSUB PROG 9:H=Q:I=F-H
50 INPUT "ゼンカイリバライビ(OR ハッコウビ)";A
60 GOSUB PROG 9:G=Q
70 GOSUB PROG 7:W=G+J:IF G=0 THEN W=0
80 IF E=0 THEN X=G+F+J:O=0:H=F: GOTO 100
90 X=I:O=C/2
100 INPUT "スタートタンカ OR 0";L
105 INPUT "エンドタンカ OR 0";M
110 INPUT "ゲンサキレート OR 0";N
120 INPUT "トリヒキゼイリツ=";T:T=1-T/R^2
130 K=C*W/365:V=10^7: GOSUB PROG 8:Y=K
140 K=C*X/365:V=10^7: GOSUB PROG 8:Z=K
143 D=1+N*F/36500
146 E=1+N*H/36500
150 IF M=0 THEN 185
155 IF L=0 THEN 220
160 K=((M*T+O+Z-Y-L)*36500)/(L*F+Y*H)
170 V=10^5: GOSUB PROG 8
180 PRINT "ゲンサキレート=";K: GOTO 100
185 IF L=0 THEN 100
188 IF N=0 THEN 100
190 K=(L*D+Y*E-Z-O)/T
200 V=10^7: GOSUB PROG 8
210 PRINT "エンドタンカ=";K: GOTO 100
220 IF N=0 THEN 100
225 IF M=0 THEN 100
230 K=(M*T+Z+O-Y*E)/D
240 V=10^5: GOSUB PROG 8
250 PRINT "スタートタンカ=";K: GOTO 100
-------- PROG 3 --------
5 PRINT "* ガイカヨキン ジッシツリマワリ *"
10 INPUT "スタートビ=";A,"エンドビ=";B
15 INPUT "ガイカ ヒョウメンレート=";C
20 GOSUB PROG 9:M=365
30 INPUT "ジキモノ-TTS=";D
35 INPUT "サキモノ-TTB OR SPREAD=";G
40 IF G>=R THEN E=G:F=E-D: GOTO 60
50 E=D+G:F=G
60 K=(C/R*E/D+F*M/(D*Q))*R
70 V=10^5: GOSUB PROG 8
80 PRINT "ニッスウ=";Q
90 IF G>=R THEN PRINT "SPREAD=";F: GOTO 110
100 PRINT "サキモノ-TTB=";E
110 PRINT "ジッシツリマワリ=";K: GOTO 30
------- PROG 4 --------
10 PRINT " * ショユウキカン リマワリ *"
20 INPUT "キサンビ=";A,"バイキャクビ=";B
25 INPUT "クーポンレート=";C
30 GOSUB PROG 9
40 INPUT "カイタンカ OR 0=";D
45 INPUT "ウリタンカ OR 0=";F
50 INPUT "ショユウキカン OR 0=";G
60 IF C=0 THEN 200
70 IF D=0 THEN 120
80 IF F=0 THEN 150
90 K=(C*Z+(F-D))*R/(D*Z)
100 V=10^5: GOSUB PROG 8
110 PRINT "ショユウキカン リマワリ=";K: GOTO 40
120 K=(F+C*Z)/(1+G*Z/R)
130 V=10^5: GOSUB PROG 8
140 PRINT "カイ タンカ=";K: GOTO 40
150 K=D*(1+G*Z/R)-C*Z
160 V=10^5: GOSUB PROG 8
170 PRINT "ウリ タンカ=";K: GOTO 40
200 IF Z=<1 THEN 70
210 IF D=0 THEN 250
220 IF F=0 THEN 270
230 K=((F/D)^(1/Z)-1)*R
240 V=10^5: GOSUB PROG 8: GOTO 110
250 K=F/((1+G/R)^Z)
260 V=10^5: GOSUB PROG 8: GOTO 140
270 K=D*(1+G/R)^Z
280 V=10^5: GOSUB PROG 8: GOTO 170
-------- PROG 5 --------
5 PRINT " *1カラ100マデノ シゼンスウノ ワ*"
10 A=0
20 FOR I=1 TO 100:A=A+I:NEXT I
30 PRINT I;A
-------- PROG 6 --------
-------- PROG 7 --------
10 INPUT "コクサイ ショキ:1(Y) OR 0(N)";J:RETURN
-------- PROG 8 --------
10 K=INT(K*V):K=K/V:RETURN
-------- PROG 9 --------
10 R=100:Y=365:K=A:S=0
20 GOSUB 100
30 O=K:Y=365.25: GOSUB 200:T=K:K=B:S=1:Y=365
40 GOSUB 100:P=K:Y=365.25: GOSUB 200:U=K
50 Q=P-O:IF Q>=365 THEN 70
60 Q=U-T
70 K=Q/365:V=10^7: GOSUB PROG 8:Z=K:RETURN
100 L=INT(K/R^2):K=K-L*R*R:IF S=0 THEN X=K
110 M=INT(K/R):N=K-M*R
120 L>=R THEN 140
130 L=L+1925
140 IF M>=3 THEN M=INT((M+1)*30.6): GOTO 160
150 L=L-1:M=INT((M+13)*30.6)
160 K=INT(L*Y)+M+N
170 IF S=0 THEN RETURN
180 IF X=229 THEN K=K+1
190 RETURN
200 K=INT(L*Y)+M+N-INT(L/R)+INT(L/400):RETURN